See:

   Dim sXML : sXML     = "<root><child>one</child></root>"
   Dim oXML : Set oXML = CreateObject( "MSXML2.DOMDocument" )
   oXML.loadXML sXML
   WScript.Echo 0, oXML.xml
   Dim ndChild : Set ndChild = oXML.documentElement.firstChild
   byRefXml ndChild
   WScript.Echo 1, ndChild.xml
   byValXml ndChild
   WScript.Echo 2, ndChild.xml
   byValValXml (ndChild)
   WScript.Echo 3, ndChild.xml

output:

=== XmlByRefVal: ByRef/ByVal for xml no
0 <root><child>one</child></root>

1 <child>two</child>
2 <child>three</child>
3 <child>four</child>
=== XmlByRefVal: 0 done (00:00:00) ====

   Function PassByVal (ByVal objectArg)

VBS will effectively still pass an reference to the original object.

All that's passed by value is the long variable, that holds the address
of the object. But there'll be no new instancing or even
cloning of member data in any way.

If you modify some of the objects data inside the body of the supposed
ByVal-function, the object data remains modified after having returned,
which clearly indicates that you worked on the same instance.

This makes a difference to languages that support true by-value-passing
  - internally creating a shallow copy (memcopy) - as does C++.

See the listing below, that shows that ByVal or ByRef makes no
difference if the parameter is an object.
You get the same effect if you use test the mechanism on
ActiveX-objects instantiated by CreateObject
rather then VBScript class-objects.

If you need copies, you have to copy the data on your own - unless
your object already supports some kind of clone mechanism.

Christoph

set obj = new ByValTest
obj.Value = 10

wsh.echo "Outside any func:", obj.Value '10
ByValPassing obj
wsh.echo "Outside any func:", obj.Value 'now 11,
              'shold remain 10 if byval would create a cpy
ByRefPassing obj
wsh.echo "Outside any func:", obj.Value 'now 12

class ByValTest
   private valueData
   public property get Value : Value = valueData : end property
   public property let Value(dat) : valueData = dat : end property
end class

sub ByValPassing(ByVal objArg)
   objArg.Value = objArg.Value + 1
   wsh.echo "Inside byval-func:", objArg.Value
end sub

sub ByRefPassing(ByRef objArg)
   objArg.Value = objArg.Value + 1
   wsh.echo "Inside byref-func:", objArg.Value
end sub